plugins {
    alias(catalog.plugins.lombok) apply false
    alias(catalog.plugins.sambal)
    id 'war'
    id 'maven-publish'
}

allprojects {

    pluginManager.withPlugin('java-library') {
        apply plugin: 'net.woggioni.gradle.lombok'

        repositories {
            maven {
                url = getProperty('gitea.maven.url')
                content {
                    includeGroup 'net.woggioni'
                    includeGroup 'com.lys'
                }
            }
            mavenCentral()
        }


        lombok {
            version = catalog.versions.lombok.get()
        }

        tasks.withType(JavaCompile) {
            options.release = 21
        }

        java {
            toolchain {
                languageVersion = JavaLanguageVersion.of(21)
            }
        }

        tasks.withType(Test) {
            useJUnitPlatform()
        }
    }

    group = 'net.woggioni'
    version = getProperty('jsf.playground.version')
}

dependencies {
    compileOnly catalog.jakarta.faces.api
    compileOnly catalog.jakarta.servlet.api
    compileOnly catalog.jakarta.enterprise.cdi.api

    implementation catalog.jakarta.faces
    implementation catalog.jakarta.el
    implementation catalog.jakarta.cdi.el.api
    implementation catalog.weld.servlet.core
    implementation catalog.weld.web

    implementation catalog.slf4j.api
    implementation catalog.log4j.slf4j2.impl
}