plugins {
    alias(catalog.plugins.kotlin.multiplatform)
    alias(catalog.plugins.kotlin.serialization)
    id 'maven-publish'
}

allprojects {
    group = 'net.woggioni'
    version = getProperty('khtml.version')

    repositories {
        maven {
            url = getProperty('gitea.maven.url')
            content {
                includeGroup 'net.woggioni'
            }
        }
        mavenCentral()
    }

    pluginManager.withPlugin('maven-publish') {
        publishing {
            repositories {
                maven {
                    name = "Gitea"
                    url = uri(getProperty('gitea.maven.url'))

                    credentials(HttpHeaderCredentials) {
                        name = "Authorization"
                        value = "token ${System.getenv()["PUBLISHER_TOKEN"]}"
                    }

                    authentication {
                        header(HttpHeaderAuthentication)
                    }

                }

            }
        }
    }
}


kotlin {
    js(IR) {
        browser()
    }
}