subprojects {
    apply plugin: 'java-library'
    apply plugin: 'maven-publish'
    repositories {
        maven {
            url = woggioniMavenRepositoryUrl
        }
        mavenCentral()
        jcenter()
    }
    group = "net.woggioni.gradle"
    version = 0.1

    dependencies {
        ['compileOnly', 'annotationProcessor', 'testCompileOnly', 'testAnnotationProcessor'].each { conf ->
            add(conf, [group: "org.projectlombok", name: "lombok", version: project['version.lombok']])
        }
        add("testImplementation", create(group: "org.junit.jupiter", name:"junit-jupiter-api", version: project["version.junitJupiter"]))
        add("testRuntimeOnly", create(group: "org.junit.jupiter", name: "junit-jupiter-engine", version: project["version.junitJupiter"]))
        add("testImplementation", gradleTestKit())
    }

    tasks.named("test", Test) {
        useJUnitPlatform()
    }

    publishing {
        repositories {
            maven {
                url = woggioniMavenRepositoryUrl
            }
        }
        publications {
            maven(MavenPublication) {
                from(components["java"])
            }
        }
    }
}

wrapper {
    gradleVersion = "7.0.2"
    distributionType = Wrapper.DistributionType.ALL
}