wdi/build.gradle

plugins {
    id 'maven-publish'
    alias catalog.plugins.lombok apply false
    alias catalog.plugins.multi.release.jar
}

ext {
    setProperty("jpms.module.name" , "net.woggioni.wdi")
}

allprojects {
    apply plugin: 'net.woggioni.gradle.lombok'

    group = "net.woggioni"
    version = getProperty("wdi.version")

    repositories {
        maven {
            url = 'https://woggioni.net/mvn'
        }
        mavenCentral()
    }

    lombok {
        version = catalog.versions.lombok.get()
    }

    test {
        useJUnitPlatform()
    }
}

dependencies {
    implementation catalog.jwo

    testImplementation catalog.junit.jupiter.api
    testRuntimeOnly catalog.junit.jupiter.engine
}

java {
    withJavadocJar()
    withSourcesJar()
}

compileJava {
    options.compilerArgs << '-parameters'
}

compileTestJava {
    options.compilerArgs << '-parameters'
}

publishing {
    repositories {
        maven {
            url = 'https://mvn.woggioni.net/'
        }
        maven {
            name = "Gitea"
            url = uri("https://woggioni.net/gitea/api/packages/woggioni/maven")

            credentials(HttpHeaderCredentials) {
                name = "Authorization"
                value = "token ${System.getenv()["PUBLISHER_TOKEN"]}"
            }

            authentication {
                header(HttpHeaderAuthentication)
            }
        }
    }
    publications {
        maven(MavenPublication) {
            from(components["java"])
        }
    }
}