pluginManagement {
    repositories {
        maven {
            url = getProperty('gitea.maven.url')
            content {
                includeGroup 'net.woggioni.gradle'
                includeGroup 'net.woggioni.gradle.lombok'
                includeGroup 'net.woggioni.gradle.envelope'
                includeGroup 'net.woggioni.gradle.multi-release-jar'
                includeGroup 'net.woggioni.gradle.graalvm.native-image'
                includeGroup 'net.woggioni.gradle.graalvm.jlink'
                includeGroup 'net.woggioni.gradle.sambal'
            }
        }
        gradlePluginPortal()
    }
}

dependencyResolutionManagement {
    repositories {
        maven {
            url = getProperty('gitea.maven.url')
            content {
                includeGroup 'com.lys'
            }
        }
    }
    versionCatalogs {
        catalog {
            from group: 'com.lys', name: 'lys-catalog', version: getProperty('lys.version')
        }
    }
}

rootProject.name = 'wson'

def includeDirs = [
    'antlr',
    'benchmark',
    'test-utils',
    'wson-cli',
    'wson-w3c-json',
    'wcfg',
]

includeDirs.each {
    include(it)
}